Macros Uo Steam

Post Reply
User avatar
Admin
Posts: 40

Macros Uo Steam

Post by Admin » Sun Dec 02, 2018 7:04 pm

Spirit Speak Raiser:

Code: Select all

if skill 'Spirit Speak' < 100
  if @injournal 'insufficient mana'
    clearjournal
    useskill 'meditation'
    while mana < maxmana
    endwhile
  else
    if skill 'Spirit Speak' < 100
      useskill "Spirit Speak"
      pause 5000
    endif
  endif
endif
 
Auto forward Teleport:

Code: Select all

autotargettilerelative 'self' 7
cast "Teleport"
 
Enemy of One-Honor:

Code: Select all

@getenemy 'murderer' 'enemy' 'criminal' 'gray' 'closest'
@cast 'Enemy of One'
@virtue! 'honor'
waitingfortarget 300
target 'enemy'
pause 1000
 
Attack closet (Primary - Secondary weapon SKill)

Code: Select all

if not inregion 'town'
  @getenemy 'murderer' 'Enemy' 'criminal' 'gray' 'closest'
  @setability 'secondary' 'on'
  @attack! 'enemy'
endif
----------------------------------
if not inregion 'town'
  @getenemy 'murderer' 'Enemy' 'criminal' 'gray' 'closest'
  @setability 'primary' 'on'
  @attack! 'enemy'
endif
 
Momentum Champ macro (Bushido)

Code: Select all

if @graphic 'righthand' == 0xf4b
  @setability 'secondary' 'on'
endif
if @timer 'curse weapon' >= 40000
  cast 'curse weapon'
  settimer 'curse weapon' 0
endif
if not @inrange 'enemy' 1
  @getenemy  'enemy' 'gray' 'murderer' 'criminal' 'nearest' 'closest'
  pause 5
  @getenemy  'enemy' 'gray' 'murderer' 'criminal' 'nearest' 'closest'
  pause 5
  @getenemy  'enemy' 'gray' 'murderer' 'criminal' 'nearest' 'closest'
endif
if @timer 'consecrate' >= 8000
  if @inrange 'enemy' 10
    cast 'consecrate weapon'
    pause 450
    @settimer 'consecrate' 0
  endif
endif
if @injournal "no valid" or @injournal "transfer the momentum"
  cast 'momentum strike'
  clearjournal
  pause 15
endif
attack 'enemy'
 
Magery

Code: Select all

////////////////////////////////////
// This macro is designed for //
// training both magery and //
// resist from 30. It is intended //
// for characters with 40+ //
// intelligence. //
// //
// Turn on loop and click play! //
////////////////////////////////////
if skill 'magery' < 100
if @injournal 'insufficient mana'
clearjournal
useskill 'meditation'
while mana < maxmana
endwhile
else
if skill 'magery' < 30
headmsg 'Buy more skill!'
stop
elseif skill 'magery' < 45
cast 'bless' 'self'
pause 1000
elseif skill 'magery' < 55
cast 'mana drain' 'self'
pause 1000
elseif skill 'magery' < 75
cast 'invisibility' 'self'
pause 1000
elseif skill 'magery' < 100
cast 'mana vampire' 'self'
pause 1000
else
headmsg 'Magery complete!'
stop
endif
endif
elseif skill 'resisting spells' < 100
if @injournal 'insufficient mana'
clearjournal
useskill 'meditation'
while mana < maxmana
endwhile
else
cast 'mana vampire' 'self'
pause 1000
endif
else
headmsg 'Magery and resisting spells complete!'
stop
endif
inscribe spellbook

Code: Select all

//===============================================================
//=---------------------Spell Book Maker------------------------=
//=-------------------------By:Hawt-----------------------------=
//=-------------------------------------------------------------=
//=--------This script will make scrolls 1-64, Place them-------=
//=-----------in the book, meditate, and adjust when------------=
//=----to use mediation Based on what scrolls you are making----=
//=----I have broke the script down pretty good in order for----=
//=--------others to learn from 'dissecting' the script --------=
//=-------------------------------------------------------------=
//===============================================================
//=Gives Target for you too select the spellbook you want filled=
//===============================================================
if not @findobject 'spellbook'
sysmsg '!!!! Target Empty Spell Book !!!!' '23'
promptalias 'spellbook'
endif
//===============================================================
//=-----List of the gump buttons for the 8 Spell Circles.-------=
//===============================================================
if not listexists 'Circle'
@createlist 'Circle'
endif
if 'list' 'Circle' == '0'
@pushlist 'Circle' '1'
@pushlist 'Circle' '8'
@pushlist 'Circle' '15'
@pushlist 'Circle' '22'
@pushlist 'Circle' '29'
@pushlist 'Circle' '36'
@pushlist 'Circle' '43'
@pushlist 'Circle' '50'
endif
//==============================================================
//=--------List of the gump buttons for each scroll------------=
//==============================================================
if not listexists 'Spells'
@createlist 'Spells'
endif
if 'list' 'Spells' == '0'
@pushlist 'Spells' '2'
@pushlist 'Spells' '9'
@pushlist 'Spells' '16'
@pushlist 'Spells' '23'
@pushlist 'Spells' '30'
@pushlist 'Spells' '37'
@pushlist 'Spells' '44'
@pushlist 'Spells' '51'
endif
//==============================================================
//=-------------List of different Mana lvls--------------------=
//==============================================================
if not listexists 'Mana'
@createlist 'Mana'
endif
if 'list' 'Mana' == '0'
@pushlist 'Mana' '4'
@pushlist 'Mana' '6'
@pushlist 'Mana' '9'
@pushlist 'Mana' '11'
@pushlist 'Mana' '14'
@pushlist 'Mana' '20'
@pushlist 'Mana' '40'
@pushlist 'Mana' '50'
endif
//==============================================================
//=--------------List all Scrolls for each spell---------------=
//==============================================================
//=----------I did not make this list i took the list----------=
//=------------from another in The script library--------------=
//=-------------------Thank you Kadoba!!-----------------------=
//=http://www.runuo.com/community/resources/fill-spellbook.57/-=
//==============================================================
if not listexists 'scrolls'
@createlist 'scrolls'
endif
if 'list' 'scrolls' == '0'
@pushlist 'scrolls' 0x1f2d // Reactive Armor
@pushlist 'scrolls' 0x1f2e // Clumsy
@pushlist 'scrolls' 0x1f2f // Create Food
@pushlist 'scrolls' 0x1f30 // Feeblemind
@pushlist 'scrolls' 0x1f31 // Heal
@pushlist 'scrolls' 0x1f32 // Magic Arrow
@pushlist 'scrolls' 0x1f33 // Night Sight
@pushlist 'scrolls' 0x1f34 // Weaken
@pushlist 'scrolls' 0x1f35 // Agility
@pushlist 'scrolls' 0x1f36 // Cunning
@pushlist 'scrolls' 0x1f37 // Cure
@pushlist 'scrolls' 0x1f38 // Harm
@pushlist 'scrolls' 0x1f39 // Magic Trap
@pushlist 'scrolls' 0x1f3a // Magic Untrap
@pushlist 'scrolls' 0x1f3b // Protection
@pushlist 'scrolls' 0x1f3c // Strength
@pushlist 'scrolls' 0x1f3d // Bless
@pushlist 'scrolls' 0x1f3e // Fireball
@pushlist 'scrolls' 0x1f3f // Magic Lock
@pushlist 'scrolls' 0x1f40 // Poison
@pushlist 'scrolls' 0x1f41 // Telekinesis
@pushlist 'scrolls' 0x1f42 // Teleport
@pushlist 'scrolls' 0x1f43 // Unlock
@pushlist 'scrolls' 0x1f44 // Wall of Stone
@pushlist 'scrolls' 0x1f45 // Arch Cure
@pushlist 'scrolls' 0x1f46 // Arch Protection
@pushlist 'scrolls' 0x1f47 // Curse
@pushlist 'scrolls' 0x1f48 // Fire Field
@pushlist 'scrolls' 0x1f49 // Greater Heal
@pushlist 'scrolls' 0x1f4a // Lightning
@pushlist 'scrolls' 0x1f4b // Mana Drain
@pushlist 'scrolls' 0x1f4c // Recall
@pushlist 'scrolls' 0x1f4d // Blade Spirit
@pushlist 'scrolls' 0x1f4e // Dispel Field
@pushlist 'scrolls' 0x1f4f // Incognito
@pushlist 'scrolls' 0x1f50 // Magic Reflection
@pushlist 'scrolls' 0x1f51 // Mind Blast
@pushlist 'scrolls' 0x1f52 // Paralyze
@pushlist 'scrolls' 0x1f53 // Poison Field
@pushlist 'scrolls' 0x1f54 // Summon Creature
@pushlist 'scrolls' 0x1f55 // Dispel
@pushlist 'scrolls' 0x1f56 // Energy Bolt
@pushlist 'scrolls' 0x1f57 // Explosion
@pushlist 'scrolls' 0x1f58 // Invisibility
@pushlist 'scrolls' 0x1f59 // Mark
@pushlist 'scrolls' 0x1f5a // Mass Curse
@pushlist 'scrolls' 0x1f5b // Paralyze Field
@pushlist 'scrolls' 0x1f5c // Reveal
@pushlist 'scrolls' 0x1f5d // Chain Lightning
@pushlist 'scrolls' 0x1f5e // Energy Field
@pushlist 'scrolls' 0x1f5f // Flamestrike
@pushlist 'scrolls' 0x1f60 // Gate Travel
@pushlist 'scrolls' 0x1f61 // Mana Vampire
@pushlist 'scrolls' 0x1f62 // Mass Dispel
@pushlist 'scrolls' 0x1f63 // Meteor Swarm
@pushlist 'scrolls' 0x1f64 // Polymorph
@pushlist 'scrolls' 0x1f65 // Earthquake
@pushlist 'scrolls' 0x1f66 // Energy Vortex
@pushlist 'scrolls' 0x1f67 // Ressurrection
@pushlist 'scrolls' 0x1f68 // Summon Air Elemental
@pushlist 'scrolls' 0x1f69 // Summon Daemon
@pushlist 'scrolls' 0x1f6a // Summon Earth Elemental
@pushlist 'scrolls' 0x1f6b // Summon Fire Elemental
@pushlist 'scrolls' 0x1f6c // Summon Water Elemental
endif
//===============================================================
//=-------Basically telling the script when to meditate---------=
//===============================================================
if mana < Mana[0]
useskill 'meditation'
while not mana == maxmana
endwhile
endif
//===============================================================
//=-----------------Checks for Blank Scrolls.-------------------=
//===============================================================
if not @findtype '0xef3' 'any' 'backpack'
sysmsg '#### No Scrolls###'
stop
endif
//===============================================================
//=---Checks for Scribe Pens, if finding one is uses the pen.---=
//===============================================================
if @usetype '0xfbf' 'any' 'backpack'
waitforgump '0x38920abd' '5000'
else
sysmsg '####No Pens ####' '23'
stop
endif
//==============================================================
//=-----------------Gump Buttons to be pressed.----------------=
//==============================================================
replygump '0x38920abd' Circle[0]
waitforgump '0x38920abd' '5000'
replygump '0x38920abd' Spells[0]
waitforgump '0x38920abd' '5000'
pause 900
//==============================================================
//=------------Checks for Scroll to be placed in book----------=
//==============================================================
if @movetype scrolls[0] 'backpack' 'spellbook' 0 0 0 'any' '1'
pause '1000'
poplist 'Spells' 'front'
poplist 'scrolls' 'front'
endif
//==============================================================
//=--------After Finishing a complete circle of spells---------=
//=-----This changes the Spell Circle and When to meditate.----=
//==============================================================
if list 'Spells' == 0
poplist 'Circle' 'front'
poplist 'Mana' 'front'
endif
//==============================================================
//=----This stops the script when completeing a full book.-----=
//==============================================================
if list 'scrolls' == 0
unsetalias 'spellbook'
sysmsg 'Spell Book Should Be Full' '23'
stop
endif
Auto attack secondary

Code: Select all

setability 'secondary' 'on'
getenemy 'murderer' 'enemy' 'criminal' 'gray' 'closest'
attack 'enemy'
 pause 1250

Code: Select all

////////////////////////////////////

//==============================================================
//=----Chival.-----=
//==============================================================

// recuerda poner el loop //
////////////////////////////////////
if skill 'chivalry' < 80
  if @injournal 'insufficient mana'
    clearjournal
    useskill 'meditation'
    while mana < maxmana
    endwhile
  else
    if skill 'chivalry' < 30
      headmsg 'Buy more skill!'
      stop
    elseif skill 'chivalry' < 45
      cast 'divine fury' 'self'
      pause 1000
    elseif skill 'chivalry' < 55
      cast 'enemy of one' 'self'
      pause 1000
    elseif skill 'chivalry' < 80
      cast 'holy light' 'self'
      pause 1000
    elseif skill 'noble sacrifice' < 80
      cast '' 'self'
      pause 1000
    else
      headmsg 'Chivalry complete!'
      stop
    endif
Necromancy

Code: Select all

////////////////////////////////////
// This macro is designed for //
// training both magery and //
// resist from 30. It is intended //
// for characters with 40+ //
// intelligence. //
// //
// Turn on loop and click play! //
////////////////////////////////////
if skill 'necromancy' < 100
  if @injournal 'insufficient mana'
    clearjournal
    useskill 'meditation'
    while mana < maxmana
    endwhile
  else
    if skill 'necromancy' < 20
      headmsg 'Buy more skill!'
      stop
    elseif skill 'necromancy' < 40
      cast 'evil omen' 'self'
      pause 1000
    elseif skill 'necromancy' < 70
      cast 'Horrific Beast'
      pause 1000
    elseif skill 'necromancy' < 100
      cast 'Lich Form' 'self'
      pause 1000
    else
      headmsg 'Necromancy complete!'
      stop
    endif
  endif
elseif skill 'resisting spells' < 100
  if @injournal 'insufficient mana'
    clearjournal
    useskill 'meditation'
    while mana < maxmana
    endwhile
  else
    cast 'weaken' 'self'
    pause 1000
  endif
else
  headmsg 'Magery and resisting spells complete!'
  stop
endif
Tailoring

Code: Select all

////////////////////////////////////
//     Uses a sewing kit. This    //
//      macro is designed for     //
//   training tailoring from 30.  //
//                                //
//  Turn on loop and click play!  //
//                                //
//      ~~Made by kdivers~~       //
////////////////////////////////////
if skill 'Tailoring' < 30
  headmsg "Buy skill from an NPC!"
  stop
elseif skill 'Tailoring' < 41.4
  if usetype 0xf9d 0x0 'backpack'
    replygump 0x38920abd 15
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 2
    waitforgump 0x38920abd 15000
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x152e 0x0 'backpack'
    endif
  endif
elseif skill 'Tailoring' < 54
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 51
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x1515 0x0 'backpack'
    endif
  endif
elseif skill 'Tailoring' < 74.6
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 58
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x1f03 0x0 'backpack'
    endif
  endif
elseif skill 'Tailoring' < 99
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 23
    pause 2000
    if diffweight < 20
      if usetype 0xf9f 0x0 'backpack'
        waitfortarget 2000
        @targettype! 0x175d 0x7d1 'backpack'
      endif
    endif
  endif
elseif skill 'tailoring' < 100
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 43
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 30
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x13db 0x0 'backpack'
    endif
  endif
else
  headmsg 'Tailoring complete!'
  stop
endif
Inscribe

Code: Select all

////////////////////////////////////////////////
// This macro is designed for                 //
// training inscription from 30-100.          //
// It is intended for characters              //
// with 40+ intelligence.                     //
//                                            //
// Setup, and click start!                    //
//                                            //
// Original Credits: kdivers and AreYouKidden //
// Edited and merged by Gitbytes              //
////////////////////////////////////////////////

// SETUP
// **NOTE** You may have to clear your Active Objects table
// Create two Organizers and preset the container sources:
  // 1. 'Restock Scribe'
    // * 100 of each reagent
    // * 100 blank scrolls
  // 2. 'Restock Pen'
    // * 3 scribe pens
// Select the "Loop" checkbox option
// Hit "Start"
// Select a Bulk Reagent source container when prompted
// Select your character reagent container when prompted
// Select a Bulk Pen source container when prompted
// Select a destination container for finished scrolls when prompted

@clearjournal
@removelist 'Scrolls'
createlist 'Scrolls'
if not @findobject 'sBulkReg'
  headmsg 'Select the bag with your Bulk Reg/scroll supply'
  promptalias 'sBulkReg'
endif
if not @findobject 'sRegBag'
  headmsg 'Select your character reg bag'
  promptalias 'sRegBag'
endif
if not @findobject 'sPenBag'
  headmsg 'Select the bag with your Bulk Pen Supply'
  promptalias 'sPenBag'
endif
if not @findobject 'sFinScroll'
  headmsg 'Select your Finished Scroll bag'
  promptalias 'sFinScroll'
endif
while not dead
  //Find and Move if more than 100 Scrolls
  for 0 to Scrolls
    if @findtype Scrolls[] 'any' 'backpack' 100 '3'
      headmsg '100 Scrolls Found Moving to Finished Bag'
      @moveitem 'found' 'sFinScroll'
    endif
  endfor
  // Spell Scrolls
  pushlist 'Scrolls' 0x1f2d // Reactive Armor
  pushlist 'Scrolls' 0x1f2e // Clumsy
  pushlist 'Scrolls' 0x1f2f // Create Food
  pushlist 'Scrolls' 0x1f30 // Feeblemind
  pushlist 'Scrolls' 0x1f31 // Heal
  pushlist 'Scrolls' 0x1f32 // Magic Arrow
  pushlist 'Scrolls' 0x1f33 // Night Sight
  pushlist 'Scrolls' 0x1f34 // Weaken
  pushlist 'Scrolls' 0x1f35 // Agility
  pushlist 'Scrolls' 0x1f36 // Cunning
  pushlist 'Scrolls' 0x1f37 // Cure
  pushlist 'Scrolls' 0x1f38 // Harm
  pushlist 'Scrolls' 0x1f39 // Magic Trap
  pushlist 'Scrolls' 0x1f3a // Magic Untrap
  pushlist 'Scrolls' 0x1f3b // Protection
  pushlist 'Scrolls' 0x1f3c // Strength
  pushlist 'Scrolls' 0x1f3d // Bless
  pushlist 'Scrolls' 0x1f3e // Fireball
  pushlist 'Scrolls' 0x1f3f // Magic Lock
  pushlist 'Scrolls' 0x1f40 // Poison
  pushlist 'Scrolls' 0x1f41 // Telekinesis
  pushlist 'Scrolls' 0x1f42 // Teleport
  pushlist 'Scrolls' 0x1f43 // Unlock
  pushlist 'Scrolls' 0x1f44 // Wall of Stone
  pushlist 'Scrolls' 0x1f45 // Arch Cure
  pushlist 'Scrolls' 0x1f46 // Arch Protection
  pushlist 'Scrolls' 0x1f47 // Curse
  pushlist 'Scrolls' 0x1f48 // Fire Field
  pushlist 'Scrolls' 0x1f49 // Greater Heal
  pushlist 'Scrolls' 0x1f4a // Lightning
  pushlist 'Scrolls' 0x1f4b // Mana Drain
  pushlist 'Scrolls' 0x1f4c // Recall
  pushlist 'Scrolls' 0x1f4d // Blade Spirit
  pushlist 'Scrolls' 0x1f4e // Dispel Field
  pushlist 'Scrolls' 0x1f4f // Incognito
  pushlist 'Scrolls' 0x1f50 // Magic Reflection
  pushlist 'Scrolls' 0x1f51 // Mind Blast
  pushlist 'Scrolls' 0x1f52 // Paralyze
  pushlist 'Scrolls' 0x1f53 // Poison Field
  pushlist 'Scrolls' 0x1f54 // Summon Creature
  pushlist 'Scrolls' 0x1f55 // Dispel
  pushlist 'Scrolls' 0x1f56 // Energy Bolt
  pushlist 'Scrolls' 0x1f57 // Explosion
  pushlist 'Scrolls' 0x1f58 // Invisibility
  pushlist 'Scrolls' 0x1f59 // Mark
  pushlist 'Scrolls' 0x1f5a // Mass Curse
  pushlist 'Scrolls' 0x1f5b // Paralyze Field
  pushlist 'Scrolls' 0x1f5c // Reveal
  pushlist 'Scrolls' 0x1f5d // Chain Lightning
  pushlist 'Scrolls' 0x1f5e // Energy Field
  pushlist 'Scrolls' 0x1f5f // Flamestrike
  pushlist 'Scrolls' 0x1f60 // Gate Travel
  pushlist 'Scrolls' 0x1f61 // Mana Vampire
  pushlist 'Scrolls' 0x1f62 // Mass Dispel
  pushlist 'Scrolls' 0x1f63 // Meteor Swarm
  pushlist 'Scrolls' 0x1f64 // Polymorph
  pushlist 'Scrolls' 0x1f65 // Earthquake
  pushlist 'Scrolls' 0x1f66 // Energy Vortex
  pushlist 'Scrolls' 0x1f67 // Ressurrection
  pushlist 'Scrolls' 0x1f68 // Summon Air Elemental
  pushlist 'Scrolls' 0x1f69 // Summon Daemon
  pushlist 'Scrolls' 0x1f6a // Summon Earth Elemental
  pushlist 'Scrolls' 0x1f6b // Summon Fire Elemental
  pushlist 'Scrolls' 0x1f6c // Summon Water Elemental
  while not dead
    //Find and Move if more than 100 Scrolls
    for 0 to Scrolls
      if @findtype Scrolls[] 'any' 'backpack' 100 '3'
        headmsg '100 Scrolls Found Moving to Finished Bag'
        @moveitem 'found' 'sFinScroll'
      endif
    endfor
    //
    //Making sure regs, pen & scrolls are stocked
    //
    //Pens
    if counttype '0xfbf' '0' 'backpack' < 1
      @useobject 'Restock Pen'
      pause 600
      organizer 'Restock Pen' 'SPenBag' 'backpack'
      while organizing
        pause 600
      endwhile
      if counttype '0xfbf' '0' 'backpack' < 1
        headmsg 'Out of Pens'
        stop
      endif
    endif
    //Black Pearl
    if counttype '0xf7a' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf7a' '0' 'backpack' < 1
        headmsg 'Out of Black Pearl'
        stop
      endif
    endif
    //Blood Moss
    if counttype '0xf7b' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf7b' '0' 'backpack' < 1
        headmsg 'Out of Blood Moss'
        stop
      endif
    endif
    //Ginseng
    if counttype '0xf85' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf85' '0' 'backpack' < 1
        headmsg 'Out of Ginseng'
        stop
      endif
    endif
    //Mandrake
    if counttype '0xf86' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf86' '0' 'backpack' < 1
        headmsg 'Out of Mandrake'
        stop
      endif
    endif
    //Nightshade
    if counttype '0xf88' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf88' '0' 'backpack' < 1
        headmsg 'Out of Nightshade'
        stop
      endif
    endif
    //Garlic
    if counttype '0xf84' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf84' '0' 'backpack' < 1
        headmsg 'Out of Garlic'
        stop
      endif
    endif
    //Sulfurous Ash
    if counttype '0xf8c' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xf8c' '0' 'backpack' < 1
        headmsg 'Out of Sulfuric Ash'
        stop
      endif
    endif
    //Blank Scrolls
    if counttype '0xef3' '0' 'backpack' < 1
      @useobject 'Restock Scribe'
      pause 600
      organizer 'Restock Scribe' 'sBulkReg' 'sRegBag'
      while organizing
        pause 600
      endwhile
      if counttype '0xef3' '0' 'backpack' < 1
        headmsg 'Out of Blank Scrolls'
        stop
      endif
    endif
    if mana < 50
      useskill 'meditation'
      while not mana == maxmana
      endwhile
    endif
    if skill 'inscription' < 30
      headmsg 'Buy more skill!'
      stop
    elseif skill 'inscription' < 55
      if usetype 0xfbf
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 22
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 51
        waitforgump 0x38920abd 2000
      endif
    elseif skill 'inscription' < 75
      if usetype 0xfbf
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 36
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 30
        waitforgump 0x38920abd 2000
      endif
    elseif skill 'inscription' < 95
      if usetype 0xfbf
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 43
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 23
        waitforgump 0x38920abd 2000
      endif
    elseif skill 'inscription' < 100
      if usetype 0xfbf
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 50
        waitforgump 0x38920abd 15000
        replygump 0x38920abd 9
        waitforgump 0x38920abd 2000
      endif
    else
      headmsg 'Inscription complete!'
      stop
    endif

User avatar
Developer
Posts: 22

Re: Macros Uo Steam

Post by Developer » Wed Dec 12, 2018 8:56 pm

Up Stealing skill
//INSTRUCTIONS: You need to put gold into your pack animal, say "All Follow Me" and stay in Felucca before run this macro
useskill 'Stealing'
waitfortarget 15000
//press objetct inspector and target your pack animal, put his serial as target
target! 0xf295
pause 1000
if @injournal 'You successfully steal the item' 'system'
warmode 'on'
pause 1000
warmode 'off'
clearjournal
pause 1000
//this type is gold(selected by graphic), from your backpack, to the serial of your pack animal
movetype 0xeed 'backpack' 0xf295 65535 65535 0
pause 600
endif
if hits < maxhits
msg 'All Follow Me'
pause 2000
endif
pause 9000

Apacze
Posts: 3

Re: Macros Uo Steam

Post by Apacze » Thu Jan 03, 2019 7:31 pm

Its a macro for healing 2 pets ("
at the same time")

Code: Select all

@cleartargetqueue
@clearjournal
if dead 'self'
  stop
endif
//Setup
if not findalias 'pet1'
  headmsg 'Select first pet'
  promptalias 'pet1'
endif
if not findalias 'pet2'
  headmsg 'Select second pet'
  promptalias 'pet2'
endif
//Heal them to full
while diffhits 'pet1' == '0' and diffhits 'pet2' == '0'
  pause 500
endwhile
if diffhits 'pet1' > diffhits 'pet2'
  if inrange 'pet1' 2
    bandage
    autotargetobject 'pet1'
    pause 2000
  endif
  @cleartargetqueue
else
  if inrange 'pet2' 2
    bandage
    autotargetobject 'pet2'
    pause 2000
  endif
  @cleartargetqueue
endif
if not @injournal 'finish' 'system'
  pause 500
  replay
else if @injournal 'finish' 'system'
  @clearjournal
  replay
elseif @injournal 'too far away' 'system'
  @clearjournal
  replay
elseif @injournal 'stay close enough' 'system'
  @clearjournal
  replay
endif

Post Reply